Syntax

Here is a Backus–Naur form representation of the full FETCH syntax in abstract form:

FETCH #

FETCH    ::= 'FETCH' entityName '(' property ( ',' property )* ')' linkedEntities* ( 'FILTER' filter )? orderBy? ( 'LIMIT' int ( ',' int )? )?

property #

property ::= ( propertyName ( 'AS' alias )? | ( 'SUM' | 'AVG' | 'STD' | 'MIN' | 'MAX' | 'COUNT' | 'CONCAT' ) '(' propertyName ')' ) 'GROUP BY'?

referenced by:

• FETCH

linkedEntities #

linkedEntities
         ::= '{' linkEntity ( ',' linkEntity )* '}'

referenced by:

• FETCH
• linkEntity

linkEntity #

linkEntity
         ::= entityName '(' 'property' ( ',' 'property' )* ')' 'FROM' propertyName 'TO' propertyName ( 'LINK TYPE' ( 'LEFT' | 'RIGHT' | 'INNER' ) )? linkedEntities* ( 'FILTER' filter )? orderBy?

referenced by:

• linkedEntities

filter #

filter   ::= ( 'AND' | 'OR' ) '(' ( condition | filter ( ',' ( condition | filter )* )? )? ')'

referenced by:

• FETCH
• filter
• linkEntity

condition #

condition
         ::= propertyName ( operator value | 'IS NULL' | 'IS NOT NULL' | 'IN' '(' value ( ',' value )* ')' | ( 'BEFORE NEXT' | 'AFTER NEXT' | 'IN NEXT' | 'BEFORE LAST' | 'AFTER LAST'
                  | 'IN LAST' ) value 'DAYS' )

referenced by:

• filter

operator #

operator ::= '=='
           | 'LIKE'
           | '>'
           | '<'
           | '>='
           | '<='
           | 'MATCH'

referenced by:

• condition

value #

value    ::= string
           | int
           | decimal

referenced by:

• condition

orderBy #

orderBy  ::= 'ORDER BY' propertyName ( 'ASC' | 'DESC' ) ( ',' propertyName ( 'ASC' | 'DESC' ) )*

referenced by:

• FETCH
• linkEntity

alias #

alias    ::= [A-Za-z_] [A-Za-z_0-9]*

referenced by:

• property

entityName #

entityName
         ::= [A-Za-z] [A-Za-z_0-9]*

referenced by:

• FETCH
• linkEntity

propertyName #

propertyName
         ::= [A-Za-z] [A-Za-z_0-9]*

referenced by:

• condition
• linkEntity
• orderBy
• property

int #

int      ::= [0-9]*

referenced by:

• FETCH
• value

decimal #

decimal  ::= [0-9]+ '.' [0-9]+

referenced by:

• value

comment #

string #

string   ::= '"' [^"]* '"'

referenced by:

• value