OAuth 2.0

SystemCreateUserByName workflow for OAuth 2.0 #

This workflow is used to create the internal user inside the framework with the information provided by OAuth 2.0. For example, in the code below is shown how to create a user when signed up for the first time into the framework through OAuth 2.0.

workflow SystemCreateUserByName;

function main (email as string) as int {
    //Creating user
    var p = CREATE user;
    p.name = email;
    p.mail = email;
    //Fetching a role
    var r =
        FETCH role (key)
        FILTER AND(name == "UI Users")
        LIMIT 1 **;
    //Setting the role for the newly created user
    if (r != null) {
        var user_role = CREATE CHILD p user_user_role;
        user_role.id_role = r.key;
    }
    //Fetching additional role
    var r1 =
        FETCH role (key)
        FILTER AND(name == "Extern")
        LIMIT 1 **;
    //Adding it to the user
    if (r1 != null) {
        var user_role = CREATE CHILD p user_user_role;
        user_role.id_role = r1.key;
    }
    //Fetching the default organization
    var org =
        FETCH organization (key)
        FILTER AND(name == "External")
        LIMIT 1 **;
    //Setting the organization to the user
    if (org.key != null) {
        p.id_organization = org.key;
    }
    //In this case a new business unit is created so it will be unqiue for all users.
    var bus = CREATE business_unit;
    bus.name = system->randomUUID();
    PUT bus;
    //Setting the business unit to the user
    if (bus.key != null) {
        p.id_business_unit = bus.key;
    }
    //Creating the user
    PUT p;
    //Returning it to OAuth 2.0
    return p.key;
}